Inicio Sistemas Operativos

Restablecer Cache de Iconos del Area de Notificación en Windows



Ultima Actualización del Artículo: Oct 9, 2016

En la semana al estar moviendo la configuración de la apariencia de Windows, instale en mi equipo algunos temas y plugins para cambiar los colores de las ventanas, vistas de la barra de tareas y el area de notificación, después de haber movido e instalado varias cosas decidí quitar todo porque no me agrado como quedo la vista personalizada, pero mi sorpresa al desinstalar y regresar todo a la configuración predeterminada mis iconos del area de notificación estaban muy pequeños, para esto la solución es limpiar el cache para restaurar la configuración predeterminada del área.

Restablecer Cache de Iconos del Área de Notificación

1.- Primeramente descargamos el archivo .bat siguiente (Quieres el código fuente al final del articulo):

2.- Ejecutamos como Administrador (Clic derecho > Ejecutar como Administrador).

3.- Seguimos los pasos que nos muestra:

3.1.- Como se cierra el proceso Explorer.exe es recomendable guardar todo lo que estemos haciendo antes y presionamos cualquier tecla para continuar.restablecer-cache-de-iconos-del-area-de-notificacion

3.2.- Al finalizar nos desplegara que registro fue eliminado y un mensaje para reiniciar el equipo, ingresamos Y y presionamos Enter, para reiniciar.restablecer-cache-de-iconos-del-area-de-notificacion-2

4.- Al iniciar nuevamente Windows debe estar restablecida el Area de Notificación.

area-de-notificacion

Código

@echo off

set regPath=HKCU\Software\Classes\Local Settings\Software\Microsoft\Windows\CurrentVersion\TrayNotify
set regKey1=IconStreams
set regKey2=PastIconsStream


echo.
echo El proceso Explorer debe ser cerrado temporalmente antes de la supresión del cache del area de notificación.
echo.
echo Favor de guardar sus documentos antes de continuar
echo.
pause


echo.
taskkill /IM explorer.exe /F
echo.
FOR /F "tokens=*" %%a in ('Reg Query "%regpath%" /v %regkey1% ^| find /i "%regkey1%"') do goto IconStreams
echo Llave de registro "IconStreams" eliminada.
echo.

:verify-PastIconsStream
FOR /F "tokens=*" %%a in ('Reg Query "%regpath%" /v %regkey2% ^| find /i "%regkey2%"') do goto PastIconsStream
echo Llave de registro "PastIconsStream" eliminada.
echo.
goto restart

:IconStreams
reg delete "%regpath%" /f /v "%regkey1%"
goto verify-PastIconsStream

:PastIconsStream
reg delete "%regpath%" /f /v "%regkey2%"


:restart
echo.
echo.
echo Usted tendrá que reiniciar su equipo para terminar de restablecer los iconos del área de notificación.
echo.
CHOICE /C:YN /M "Reinciar ahora?"
IF ERRORLEVEL 2 goto no
IF ERRORLEVEL 1 goto yes


:no
echo.
echo.
echo Reiniciando servicio Explorer.... 
echo.
echo Favor de reiniciar su equipo para terminar de restablecer los iconos del área de notificación.
echo.
start explorer.exe
pause
exit /B

:yes
shutdown /r /f /t 00

Créditos para Shawn Brink de tenforums

 

 

Artículos que te pueden interesar:
 
COMPARTIR
Mi nombre es Fernando, soy analista de sistemas actualmente trabajo en una empresa con mas de 200 empleados que utilizan equipo de computo al cual se les da soporte en el departamento. Uno de mis pasatiempos fuera de la empresa es escribir artículos para PortalMasTips donde documento los problemas, inquietudes y detalles interesantes que se presentan.

Deja un comentario...